xmq = ws, (-node, ws)*.
node = element | keyvalue | quote | entity | comment | line_comment | doctype | pi | xml.
element = @name, (ws, attributes)?, (ws, children)?.
children = -'{', ws, (-node, ws)*, -'}'.
keyvalue = @name, (ws, attributes)?, ws, -'=', ws, -value.
attributes = -'(', ws, (attr, ws)*, -')'.
attr = @name, (ws, -'=', ws, -value)?.
value = text | quote | entity | compound.
compound = -'(', ws, ((quote | entity), ws)*, -')'.
name = ['a'-'z'; 'A'-'Z'; '_'], -namechar*, !namechar.
-namechar = ['a'-'z'; 'A'-'Z'; '0'-'9'; '-'; '_'; '.'; ':'; '#'].
text = !'//', !'/*', ~['&'; '='; ' '; #9; #a; #d; #a0; #2000-#2003; '('; ')'; '{'; '}'; "'"; '"'],
safe*, !safe.
-safe = ~[' '; #9; #a; #d; #a0; #2000-#2003; '('; ')'; '{'; '}'; "'"; '"'].
entity = -'&', -namechar*, -';'
| -'&', ['0'-'9'; 'a'-'f']+, !namechar, !';'.
quote = -sq | -dq.
-sq = -"''", !"'"
| -sq1
| -sq3
| -sq4
| -sq5
| -sq6
| -sq7
| -sq8
| -sq9.
-sq1 = -"'", !"'", (~["'"])*, -"'", !"'".
-sq3 = -"'''", !"'", (~["'"] | "'", ~["'"] | "''", ~["'"])*, -"'''", !"'".
-sq4 = -"''''", !"'", (~["'"] | "'", ~["'"] | "''", ~["'"] | "'''", ~["'"])*, -"''''", !"'".
-sq5 = -"'''''", !"'", (~["'"] | "'", ~["'"] | "''", ~["'"] | "'''", ~["'"] | "''''", ~["'"])*, -"'''''", !"'".
-sq6 = -"''''''", !"'", (~["'"] | "'", ~["'"] | "''", ~["'"] | "'''", ~["'"] | "''''", ~["'"] | "'''''", ~["'"])*, -"''''''", !"'".
-sq7 = -"'''''''", !"'", (~["'"] | "'", ~["'"] | "''", ~["'"] | "'''", ~["'"] | "''''", ~["'"] | "'''''", ~["'"] | "''''''", ~["'"])*, -"'''''''", !"'".
-sq8 = -"''''''''", !"'", (~["'"] | "'", ~["'"] | "''", ~["'"] | "'''", ~["'"] | "''''", ~["'"] | "'''''", ~["'"] | "''''''", ~["'"] | "'''''''", ~["'"])*, -"''''''''", !"'".
-sq9 = -"'''''''''", !"'", (~["'"] | "'", ~["'"] | "''", ~["'"] | "'''", ~["'"] | "''''", ~["'"] | "'''''", ~["'"] | "''''''", ~["'"] | "'''''''", ~["'"] | "''''''''", ~["'"])*, -"'''''''''", !"'".
-dq = -'""', !'"'
| -dq1
| -dq3
| -dq4
| -dq5
| -dq6
| -dq7
| -dq8
| -dq9.
-dq1 = -'"', !'"', (~['"'])*, -'"', !'"'.
-dq3 = -'"""', !'"', (~['"'] | '"', ~['"'] | '""', ~['"'])*, -'"""', !'"'.
-dq4 = -'""""', !'"', (~['"'] | '"', ~['"'] | '""', ~['"'] | '"""', ~['"'])*, -'""""', !'"'.
-dq5 = -'"""""', !'"', (~['"'] | '"', ~['"'] | '""', ~['"'] | '"""', ~['"'] | '""""', ~['"'])*, -'"""""', !'"'.
-dq6 = -'""""""', !'"', (~['"'] | '"', ~['"'] | '""', ~['"'] | '"""', ~['"'] | '""""', ~['"'] | '"""""', ~['"'])*, -'""""""', !'"'.
-dq7 = -'"""""""', !'"', (~['"'] | '"', ~['"'] | '""', ~['"'] | '"""', ~['"'] | '""""', ~['"'] | '"""""', ~['"'] | '""""""', ~['"'])*, -'"""""""', !'"'.
-dq8 = -'""""""""', !'"', (~['"'] | '"', ~['"'] | '""', ~['"'] | '"""', ~['"'] | '""""', ~['"'] | '"""""', ~['"'] | '""""""', ~['"'] | '"""""""', ~['"'])*, -'""""""""', !'"'.
-dq9 = -'"""""""""', !'"', (~['"'] | '"', ~['"'] | '""', ~['"'] | '"""', ~['"'] | '""""', ~['"'] | '"""""', ~['"'] | '""""""', ~['"'] | '"""""""', ~['"'] | '""""""""', ~['"'])*, -'"""""""""', !'"'.
line_comment = -'//', -lcrest, (-#a | !~[]).
-lcrest = '/', -lcrest | !['/*'], ~[#a]*.
comment = -c1
| -c2
| -c3
| -c4
| -c5
| -c6.
-c1 = -'/*', p1, -'*/', (-'*', p1, -'*/')*, !'/'.
p1>part = (~['*'] | '*', !'/')*.
-c2 = -'//*', p2, -'*//', (-'*', p2, -'*//')*, !'/'.
p2>part = (~['*'] | '*', !'//')*.
-c3 = -'///*', p3, -'*///', (-'*', p3, -'*///')*, !'/'.
p3>part = (~['*'] | '*', !'///')*.
-c4 = -'////*', p4, -'*////', (-'*', p4, -'*////')*, !'/'.
p4>part = (~['*'] | '*', !'////')*.
-c5 = -'/////*', p5, -'*/////', (-'*', p5, -'*/////')*, !'/'.
p5>part = (~['*'] | '*', !'/////')*.
-c6 = -'//////*', p6, -'*//////', (-'*', p6, -'*//////')*, !'/'.
p6>part = (~['*'] | '*', !'//////')*.
doctype = -'!DOCTYPE', ws, -'=', ws, -value.
pi = -'?', @piname>name, ws, -'=', ws, -value.
piname = -namechar+, !namechar.
xml = xelement.
-xelement = '<', xname, xattr*, xs, ('/>' | '>', xcontent*, '</', xname, xs, '>').
-xattr = xs, xname, xs, '=', xs, ('"', ~['"']*, '"' | "'", ~["'"]*, "'").
-xcontent = ~['<']+, !~['<'] | xelement | xcomment | xcdata | xpi.
-xcomment = '<!--', (~['-'] | '-', ~['-'])*, '-->'.
-xcdata = '<![CDATA[', (~[']'] | ']', ~[']'] | ']]', ~['>'])*, ']]>'.
-xpi = '<?', (~['?'] | '?', ~['>'])*, '?>'.
-xname = ['a'-'z'; 'A'-'Z'; '_'; ':'], xnamechar*, !xnamechar.
-xnamechar = ['a'-'z'; 'A'-'Z'; '0'-'9'; '-'; '_'; '.'; ':'].
-xs = xschar*, !xschar.
-xschar = [' '; #9; #a; #d].
-ws = (-wsstart, -wschar*)?, !wsstart.
-wsstart = -[' '; #a; #d].
-wschar = -[' '; #a; #d; #a0; #2000-#2003].